ZenTech - c

C'est curieux chez les marins ce besoin de faire des phrases

hr — Tue, 18 Mar 2008 15:47:00 +0100

Suite à une remarque judicieuse j'ai été obligé de gérer un petit cas particulier qui conduisait à un conflit. Le script sed est maintenant modifié, ce n'est pas extrêmement propre mais c'est assez efficace. Le bout du script concerné est :

# remove /* */ comments, multiline or not
/\/\*/{
    # special case of /*/ starting comments that fools the next test
    s:/\*/:/\* /:
    :mline
    /\*\// {
        s:/\*.*\*/::
        b mlineend
    }
    N
    b mline
}
:mlineend

Pour en finir avec Lulu la Nantaise

hr — Mon, 17 Mar 2008 12:32:00 +0100

Au final, je me suis occupé des espaces, le but de ce script étant au départ de fournir un code nettoyé qui pourra passer au banc des statistiques. Le script sed est disponible et placé sous license type *BSD. Quelques corrections d'erreur et de nouvelles fonctions constituent cette dernière version du script.

J'utilise un petit fichier de définition test.h :

/*
 * Big story here
 * my life
 */
// one line
#define HEHE 1

/* includes */
#include "blah"
#include "foo" // end line comment

#include /* weird comment */ "pouet"
int woop /* to see */
/* let's continue with weird comments */ void sigpipe_handle(int);

/*-------------
  bloh
---------------*/
int main(int argc, char **argv);
int parseCommandLine(int argc, char* argv[]);

Ce qui donne, une fois passé par sed :

$ sed -nf ccmtstrip.sed test.h
#define HEHE 1
#include "blah"
#include "foo"
#include "pouet"
int woop
void sigpipe_handle(int);
int main(int argc, char **argv);
int parseCommandLine(int argc, char* argv[]);

Les commentaires déssoudés par Jo le trembleur

hr — Sat, 15 Mar 2008 21:21:00 +0100

La version précédente du script sed ne me convenait pas. Elle ne gérait pas certaines formes de commentaires horribles, qui mériterait une sentence extrême et douloureuse. C'est maintenant chose rêglée avec une version améliorée.

#!/usr/bin/sed -nf

# remove single line comments
/^\/\//d

# remove /* */ comments, multiline or not
/\/\*/{
    :mline
    /\*\// {
        s:/\*.*\*/::
        b mlineend
    }
    N
    b mline
}
:mlineend

# remove empty lines
/^$/d

p

Il peut arriver que certains espaces inutiles apparaissent dans le code suite à la suppression des commentaires multiligne mais ce n'est pas fondamentalement un problème.

Du C par Teddy de Montreal

hr — Fri, 14 Mar 2008 17:25:00 +0100

" ... un fondu qui travaillait qu'à la dynamite." Je me suis mis en tête de compter le nombre de lignes efficaces d'un développement en C. Par ligne efficace j'entends le nombre de lignes de code vraiment compilées. Je dois donc éliminer les commentaires sous leurs diverses formes et les lignes blanches. Et comme j'aime bien me faire mal, au lieu de faire ça en 10 minutes en Perl ou Python, je l'ai fait grâce à sed(1).

Ce script sed doit donc gérer les lignes blanches, les commentaires sur une ligne commençant pas '//', les commentaires sur plusieurs lignes (ou pas) du type /* comment */. Ca donne alors le script suivant :

#!/bin/sed -nf

# remove empty lines
/^$/d
# remove single line comments
/^\/\//d

# remove /* */ comments, multiline or not 
/\/\*/{
    :mline
    /\*\//b mlineend
    N
    b mline
    :mlineend
    d
}
p

Le seul passage qui me semble nécessiter une explication est celui qui gère les commentaires sur plusieurs lignes. Ce qui est fait là est assez simple (sisi c'est vrai) : on ne traite que les lignes comprenant '/*', si la ligne comprend aussi '*/' on passe à la balise mlineend, sinon on ajoute la ligne suivante aux lignes déjà lues et on passe à la balise mline (boucle). Le saut à la balise mlineend provoque la destruction des lignes lues et le passage à la ligne suivante en recommençant le script.
On finit par afficher la ligne (grâce à 'p') si aucun des cas précédents ne s'est produit.

Le défaut de ce script est de ne pas gérer les cas où les commentaires sont mixés avec du code. Je pense l'améliorer dans un deuxième temps pour prendre en compte ces cas.

Mise à jour: une nouvelle version de ce script règle ces soucis.